-
1. In Brief
2. Intro
3. Design
4. Construction
5. Measurements
6. SPICE modeling
7. Discussion, variants, improvements
8. References
|
2. Intro 3. Design 4. Construction 5. Measurements 6. SPICE modeling 7. Discussion, variants, improvements 8. References
|
|
Many other tubes can be used in place of EL34/6CA7: 6V6, 6L6, 6550, KT66, KT88, KT90... and there are more. This is so because all these tubes have the same pin-out and the bias can be adjusted.
Without doubts, HF-60 is a very fine amplifier, delivering powerful and refined classic penthode/ultralinear PP sound. Can it be converted to a DHT no-feedback, all-triode amplifier? Thoughts of drilling the chassis for 4 pin sockets, adding filaments transformers producing 5V (for 300B) or 2.5V (for 2A3) render this idea as very bad... until we realize that there is an octal equivalent of 2A3 called 6B4G (Russian name is 6C4C). This is a 6.3V-filament DHT with octal base and 2A3 construction. What about its pin-out? Let's compare. EL34/6CA7 is on the left, 6B4G is on the right.
|
6B4G is "just like" 6CA7 without the cathode and the screens...
|
OK, the pin-out is *almost* the same. Almost, except the cathode "does not exist" in 6B4G, it is the filament that is the cathode. An idea of connecting that to the ground represents 90% of the DHT mod.
|
EL34/6CA7 in ultra-linear push-pull connection, with fixed bias. The cathodes sit on the ground (the 10 ohm resistors are for bias measurement.
|
The cathode sits on the ground and the grid is at -35V. Each tube runs in class AB with ~50mA of idle current (this will differ for other penthode types). When 6B4Gs are inserted in the sockets, no current will flow unless the filaments are connected the ground. Once it is done, the power stage becomes "operating". Except that -35v bias is insufficient for low-mu 6B4Gs, which will overheat in seconds. An extra 15-20v would be needed to bias 6B4Gs into a regime dissipating 15-16W. This will also mean class AB. HF-60's bias supply can not provide that much voltage unless the resistor R26 is reduced to ~10K. This also somewhat reduces the performance of the RC filtering (C4).
There is another, more clever solution: instead of connecting the filaments to the ground, connect them to an autobiasing resistor (bypassed). The value of the resistor can be selected so that it provides the additional voltage. Thus the biasing scheme will be a combination of fixed bias and autobias. To control the hum, the filaments must be connected to the autobias resistor via a hum-balancing potentiometer.
Interestingly, with this mod the power stage shown above does not change. EL34s can be inserted and the amplifier will operate in stock mode.
There are few improvements still needed to make this idea practical. First, even if 6B4Gs can withstand 500V running in deep AB regime, this is above the recommended ratings. 350V plate-cathode would be more appropriate. Besides, 350v allows to run 6B4Gs in class A, at ~45-50mA per tube.
The output stage running in class A means the feedback can be reduced or removed. Trying a DHT PP is a treat! Yet removing the feedback will greatly increase the hum. The solution is to add an extra RC or RCL cascade to the power supply, which will remove much ripple and also will lower the B+ to ~ 400V. Finally, once the feedback is lifted, EF86 no longer needs running in penthode mode. Eric Barbour (try to find his Svetlana tech articles cached on the web) hails triode-strapping of Svetlana EF86s (a.k.a. USSR's 6-zhe-32-pe), reporting low distortion and impressive plate swing. The fact that triode-strapping reduces amplification is very handy in our case, since otherwise the open-loop gain would be uncomfortably high. Yet check high-frequency response - the input potentiometer may not be useable, if EF86 is in triode mode and the amp is in no-feedback position, unless it is replaced by a 100k pot.
|
The modifications are in red ink. The choke is assumed to have resistance of ~400ohm. A resistor can be used instead of the choke. Since in the 21 century we frequently have 120V and more in AC wall sockets, GRN-BLK should be used instead of the stock primary. It's very fortunate that HF60 provides the 132VAC tap.
|
|
The modifications are in red ink. The T is the mod position and P is stock.
|
|
You can see a pair of recent-production Sovtek monoplate 6B4Gs in pace of EL34s.
|
|
Inside, you see the autobias circuit in the upper right corner and extra PS filtering in the left corner.
|
This prototype runs class A 6B4Gs with no feedback and with triode-strapped EF86, but can not any longer run the tubes in the original ultra-linear, class AB, NFB mode. However, all that is required is a 2-way, 3-pole switch as shown on the schematics above.
|
1 W RMS out. #rd harmonic is very low thanks to DHTs and good linearity of 6SN7s.
|
|
3 W RMS. 3rd dominates as it should be in PP mode, but is still pretty low.
|
|
N.B. Simulation results presented in the next section show that the performance can be better. In part, the performance of the prototype mod is subotimal because wired as presented here (you can see this wiring on the picture). This wiring is suboptimal and is inferior to the schematic shown above because the driver stage and the phase splitter receive less B+ than they should, and that results in elevated harmonic distortion.
|
|
EF86 is shown in triode mode. V6 represent the fixed bias. The autobias resistor is chosen to be 350 ohm. While the stock configuration feeds the input tube with 150V, the splitters with 420V, increasing that to 200V and 430V respectively gives better distortion patterns, as shown below.
|
The setup shown (40V fixed bias plus 350 ohm autobias) pushes the tubes into ~41mA, deep A class.
|
This is 150V, 430V configuration, optimized for least even harmonics. Slightly surprisingly, this also results in highest odd harmonics.
|
|
Minimizing the odd harmonics results in slight imbalance, but sonic signature is probably very nice.
|
|
This corresponds to 200V/430V configuration and the best harmonics signature provided with 27k/27.5k values of the resistors.
|
Some details regards this simulation. 6SN7GTBs are Koren Improved models, with Koren model parameters. EF86, triode strapped, is Koren Improved triode model with parameters I found applying my interactive parameter-finding tool, see [4], over Svetlana-published triode curves:
** EF86 as TRIODE ******************************************************
* Created on Mon Aug 02 13:20:50 PDT 2004 using tube.model.finder.PaintKIT
* data URL: http://www.svetlana.com/graphics/products/pdf/EF86.pdf
*--------------------------------------------------
.SUBCKT TRIODE_EF86 1 2 3 ; P G K ;
+ PARAMS: CCG=3P CGP=4.4P CCP=4.9P RGI=2000
+ MU=37.2960 EX=1.3929 KG1=2010.0 KP=318.0 KVB=15.0 VCT=1.104
*--------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG
+ (1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$
I also have developed a model for 6J32P, the Russian equivalent of EF86, derived from Klausmobile measurmens done in triode mode:
** EF86_6J32P_T *********************************************************
* Created on Wed Aug 04 14:49:21 PDT 2004 using tube.model.finder.PaintKIT
* data URL: http://klausmobile.narod.ru/testerfiles/6j32p.htm
* this is a better match to klaus data than the above....
* interestingly, klaus' data is more linear
*--------------------------------------------------
.SUBCKT TRIODE_EF86_6J32P_T 1 2 3 ; P G K ;
+ PARAMS: CCG=3P CGP=1.4P CCP=1.9P RGI=2000
+ MU=34.1258 EX=1.5739 KG1=2422.05 KP=334.0908 KVB=1.5 VCT=0.6955
*--------------------------------------------------
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+(VCT+V(2,3))/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G ; TO AVOID FLOATING NODES
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
R1 2 5 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
I wanted that mainly because I was afraid Svetlanas' curves are not exactly real; Klausmobile data is definitely real. Yet it turns out that Svetlana's data is even less linear, so both models can be claimed "realistic". To simulate 6B4Gs, I could of use a 3-pin 2A3 model but what shown is a 4-pin device with 6.3 VAC applied to filaments... This is a model that takes into account the physics of the filament, something I call composite triode model. It was derived, again, using the curve painter tool [4] over the audiomatica 2a3 plate curves. The composite model is as following:
.SUBCKT 2a3-composite 1 2 3 4 ; P G K1 K2
+ PARAMS: RGI=2000
** audiomatica
+ MU=4.58 EX=1.512 KG1=1710.0 KP=40.8 KVB=1188.0 VCT=-2.24
** ??old + MU=4.2 EX=1.4 KG1=1500 KP=60 KVB=300 RGI=2000
+ CCG=7.5P CGP=16P CCP=5.5P
RFIL_LEFT 3 31 .25
RFIL_RIGHT 4 41 .25
RFIL_MIDDLE 31 41 .5
E11 32 0 VALUE={V(1,31)/KP*LOG(1+EXP(KP*(1/MU+V(2,31)/SQRT(KVB+V(1,31)*V(1,31)))))}
E12 42 0 VALUE={V(1,41)/KP*LOG(1+EXP(KP*(1/MU+V(2,41)/SQRT(KVB+V(1,41)*V(1,41)))))}
RE11 32 0 1G
RE12 42 0 1G
G11 1 31 VALUE={(PWR(V(32),EX)+PWRS(V(32),EX))/(2*KG1)}
G12 1 41 VALUE={(PWR(V(42),EX)+PWRS(V(42),EX))/(2*KG1)}
RCP1 1 3 1G
RCP2 1 4 1G
C1 2 3 {CCG} ; CATHODE-GRID
C2 2 1 {CGP} ; GRID=PLATE
C3 1 3 {CCP} ; CATHODE-PLATE
D3 5 3 DX ; FOR GRID CURRENT
D4 6 4 DX ; FOR GRID CURRENT
RG1 2 5 {RGI} ; FOR GRID CURRENT
RG2 2 6 {RGI} ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$
The model of the TO330 transformer is lossage-reflecting but with ideal core:
*******************************************************************
.SUBCKT TRANS_PP_TO330 1 2 3 4 5
+PARAMS: LPRIM=250H LLKG=7mH RPRIM=240 CPRIM=3NF LRATIO={8/4500}
.PARAM QFCTR={LPRIM/LLKG} ; Q-FACTOR.
*--- 1st half
RP1 1 11 {RPRIM}
LPleak 11 12 {LLKG}
LP1 12 5 {LPRIM}
CS1 12 5 {CPRIM}
*--- second half
RP2 2 21 {RPRIM}
LPleak2 21 22 {LLKG}
LP2 5 22 {LPRIM}
CS2 22 5 {CPRIM}
LP3 3 4 {LPRIM*LRATIO}
KALL LP1 LP2 LP3 {1-1/(QFCTR)} ; COUPLING
.ENDS
*******************************************************************
Few minor changes: the 1Mom input resistor R1 *must* be replaced by a 100K resistor. This is very useful even for the stock mode and is a must for EF86 running as no-feedback triode-strapped. The power cord was replaced by a durable computer-grade 3-prong. When the feedback is removed, hum may be originating due to grounding. In this case, star grounding, even partial, should be tried to fix the problem.
The mod is very versatile; thus, 'T' position, as shown on the drawings in red ink, can be tried to run not only DHTs, but any of the tubes from the EL34 family as well. Do not expect as smooth sound (due to comparatively higher odd harmonics) but still this mode worth experimenting with. Make sure the tubes *are* biased into class A territory! Some new production KT88 and KT90 tubes are reported to have very low 3rd harmonic distortion when ran in triode-mode; let your ears or your spectroscope to verify that.... Rigorous matching with spectrum analyzer may be required to achieve good results.
Since the performance directly depends on how well the phase splitter behaves, tube selection and adjustments for it are crucial. A linear 6sn7 tube with perfectly matched halves will result in much less overall distortion. Still, even with perfectly equal triodes the load resistors need differ slightly; the stock values are 30k/27k; SPICE analysis suggest 27.5K as producing the least distortion. For practical purposes, wiring a 5K potentiometer in series with 24K potentiometer makes lots of sense. Another solution - two 27K fixed resistors into a balancing 5k potentiometer.
Increasing the B+ on the driver slightly above what is present is the schematic is yet another way to lower harmonics even further. For this, R24 and R14 can be reduced.
Next is more subtle: should the 18k resistor in the cathodes of the splitter be replaced by a current source? How much this complexity would pay back? Similarly, would a "longer" long-tail resistor, fed from a negative voltage supply decrease distortion? By how much? SPICE analysis done in [3] hints that yes, both measures do reduce distortion, but only marginally. Despite its simplicity, the default configuration is capable to deliver very good performance - if it is balanced for least distortion and tuned for each 6SN7 individually.
Does EF86 add to the overall sonic signature? Would a change in the first tube alter the sound? The answers are "yes". Without the first tube, the schematic can produce very symmetrical signal - you can find more on this subject in [3]. The domination of 2nd harmonic above 3rd as seen in the SPICE Simulation section is due to the first stage.
[2] Mullard 5-20 topology http://www.bonavolta.ch/hobby/en/audio/el34_1.htm
[3] SPICE analysis of Mullard 5-20 topology http://www.dmitrynizh.com/eico-hf87.htm
[4] http://www.dmitrynizh.com/tubeparams_image.htm
[5] JE Labs 2A3 PP based on Mullard topology http://www.angela.com/catalog/how-to/JE_Labs/PP_2A3/